# 튜토리얼

Visual Basic 개발환경에서 팝빌 SDK를 추가하고, 현금영수증 즉시 발행 (RegistIssue) API를 호출하는 기본 과정을 단계별로 따라 해볼 수 있도록 구성된 가이드 입니다.

## 1. POPBiLL SDK 추가

① 팝빌 연동자료실에서 Visual Basic SDK 예제코드 다운로드 후 압축을 해제합니다.

② 압축해제한 SDK 예제 프로젝트의 Linkhub/ Popbill\*/ 폴더에 포함된 클래스모듈을 기존 프로젝트의 클래스모듈로 추가합니다.

![](https://developers.popbill.com/images/guide/getting-started/image-tutorial-append-sdk-vb-cashbill.png)

## 2. POPBiLL SDK 설정

Window 폼 코드에 API Key 와 클래스를 선언하고 Form\_Load() 서브모듈에 현금영수증 클래스 초기화 코드를 추가합니다.

① Form API Key, 클래스 객체 선언

```vb
Option Explicit


  ' API Key
  ' - 연동신청 시 발급받은 인증 정보(LinkID, SecretKey로 구성)
  ' • LinkID: 파트너를 식별하기 위한 고유 식별자
  ' • SecretKey: API 인증토큰 발급에 사용되는 키
  '
  ' TODO: 아래 LinkID, SecretKey를 발급받은 정보로 교체해 주세요.
Private Const LinkID = "TESTER"
Private Const SecretKey = "SwWxqU+0TErBXy/9TVjIPEnI0VTUMMSQZtJf3Ed8q3I="


' 현금영수증 서비스 객체 선언
Private CashbillService As New PBCBService
```

② Form\_Load() 서브모듈

```vb
Private Sub Form_Load()


  ' 현금영수증 서비스 객체 초기화
  CashbillService.Initialize LinkID, SecretKey


  ' 연동환경(테스트/운영) 설정
  ' - 연동환경을 테스트 또는 운영으로 설정합니다.
  ' • True: 테스트 환경으로 설정
  ' • False(default) : 운영 환경으로 설정
  '
  ' ※ 운영전환 이후부터 IsTest 설정 변경만으로 자유롭게 환경 전환(테스트<->운영)이 가능합니다.
  CashbillService.IsTest = True


  ' 인증토큰 IP 일치 검증 사용 여부
  ' - 인증토큰을 발급받은 IP와, 그 토큰을 사용하여 API를 호출하는 IP가 같은지를 검사합니다.
  '   (토큰이 외부로 유출되어도 다른 IP에서는 사용하지 못하도록 막는 보안 장치)
  ' • True(사용, default) : 두 IP가 일치할 때만 API 호출 허용
  ' • False(미사용) : IP 일치 검사를 생략
  '
  ' ※ False는 토큰 발급 시점의 IP와 API 호출 시점의 IP가 달라질 수 있는 환경에서 사용
  '   예) 오토스케일링, 로드밸런서, NAT 등으로 호출 IP가 유동적인 클라우드 환경
  CashbillService.IPRestrictOnOff = True


  ' 로컬시스템 시간 사용 여부
  ' - 현재시각 기준을 설정합니다.
  ' • True(사용) : 로컬시스템 시간 사용
  ' • False(미사용, default) : 팝빌 서버의 시간을 사용
  '
  ' ※ 현재시각은 주로 인증토큰 발급 및 만료 판단 등에 사용됩니다.
  ' ※ 이 설정은 홈택스 수집 기간, 세금계산서 작성일자, 발행일자 같은 업무 데이터의 날짜값을 변경하는 옵션이 아닙니다.
  ' ※ 로컬 서버 시간이 정상 동기화되어 있으면 일반적으로 True를 사용하고 서버 시간 오차로 인증 실패가 의심되거나
  '   서버 시간을 신뢰하기 어려운 환경이면 False를 사용합니다.
  CashbillService.UseLocalTimeYN = False
End Sub
```

## 3. RegistIssue 기능 구현

Form에 버튼을 생성하고 버튼의 Click Event 코드에 현금영수증 즉시 발행 (RegistIssue) 함수를 작성합니다.

```vb
Private Sub btnRegistIssue_Click()
    Dim corpNum As String
    Dim Cashbill As New PBCashbill
    Dim Response As PBResponse


    ' 팝빌회원 사업자번호, "-" 제외
    corpNum = "1234567890"


    ' 문서번호
    ' 문서 관리를 위해 파트너가 할당하는 식별번호
    ' 1~24자리 영문 대소문자, 숫자, 특수문자('-','_')로 구성
    Cashbill.mgtKey = "20250314-01"


    ' 거래일시, 형식(yyyyMMddHHmmss)
    ' 발행기준 전일부터 당일까지 입력 가능
    ' 미입력시 기본값(발행일시) 처리됨
    Cashbill.tradeDT = "20250319093919"


    ' 문서형태
    Cashbill.tradeType = "승인거래"


    ' 거래구분, [소득공제용, 지출증빙용] 중 기재
    Cashbill.tradeUsage = "소득공제용"


    ' 거래유형, [일반, 도서공연, 대중교통] 중 기재
    Cashbill.tradeOpt = "일반"


    ' 과세형태, [과세, 비과세] 중 기재
    Cashbill.taxationType = "과세"


    ' 합계금액, 공급가액 + 부가세 + 봉사료
    Cashbill.totalAmount = "11000"


    ' 공급가액
    Cashbill.supplyCost = "10000"


    ' 부가세
    Cashbill.tax = "1000"


    ' 봉사료
    Cashbill.serviceFee = "0"


    ' 가맹점 사업자번호, "-" 제외 10자리
    Cashbill.franchiseCorpNum = corpNum


    ' 가맹점 종사업장 식별번호
    Cashbill.franchiseTaxRegID = ""


    ' 가맹점 상호
    Cashbill.franchiseCorpName = "발행자 상호"


    ' 가맹점 대표자 성명
    Cashbill.franchiseCEOName = "발행자 대표자"


    ' 가맹점 주소
    Cashbill.franchiseAddr = "발행자 주소"


    ' 가맹점 전화번호
    Cashbill.franchiseTEL = "070-1234-1234"


    ' 식별번호, 거래구분에 따라 작성
    ' 소득공제용 - 주민등록/휴대폰/카드번호/자진발급용 번호(010-000-1234) 기재가능
    ' 지출증빙용 - 사업자번호/주민등록/휴대폰/카드번호 기재가능
    Cashbill.identityNum = "0101112222"


    ' 주문 상품명
    Cashbill.itemName = "주문상품명"


    ' 주문번호
    Cashbill.orderNumber = "주문번호"


    ' 구매자(고객) 성명
    Cashbill.customerName = "구매자명"


    ' 구매자(고객) 이메일
    ' 팝빌 개발환경에서 테스트하는 경우에도 안내 메일이 전송되므로,
    ' 실제 구매자의 메일주소가 기재되지 않도록 주의
    Cashbill.email = "test@test.com"


    ' 구매자(고객) 휴대폰
    Cashbill.hp = "010-111-222"


    ' 구매자 알림문자 전송 여부
    ' 알림문자 전송시 포인트가 차감되며, 전송실패시 환불처리됨
    Cashbill.smssendYN = False


    Set Response = CashbillService.RegistIssue(corpNum, Cashbill)


    If Response Is Nothing Then
        MsgBox ("응답코드 : " + CStr(CashbillService.LastErrCode) + vbCrLf + "응답메시지 : " + CashbillService.LastErrMessage)
        Exit Sub
    End If


    MsgBox ("응답코드 : " + CStr(Response.code) + vbCrLf + "응답메시지 : " + Response.message + vbCrLf + "국세청승인번호 : " + Response.confirmNum + vbCrLf + "거래일자 : " + Response.tradeDate)
End Sub
```

## 4. API 응답결과 확인

API 호출 응답결과는 다음과 같습니다.

| 구분 | 응답                                                                                            |
| -- | --------------------------------------------------------------------------------------------- |
| 성공 | code : 1                                                                                      |
| 실패 | code : 오류코드 (8자리 음의 정수) [\[오류코드\]](https://developers.popbill.com/error-code) message : 오류메시지 |