# 튜토리얼

Delphi 개발환경에서 팝빌 SDK를 추가하고, 사업자등록상태 대량조회 (CheckCorpNums) API를 호출하는 기본 과정을 단계별로 따라 해볼 수 있도록 구성된 가이드 입니다.

## 1. POPBiLL SDK 추가

팝빌 연동자료실에서 Delphi SDK 예제코드 다운로드 후 압축을 해제합니다.

압축해제한 SDK 예제코드에서 Linkhub/ Popbill/ PopbillTaxinvoice/ 각 폴더의 pas파일 3개를 프로젝트 유닛으로 추가합니다.

## 2. POPBiLL SDK 설정

아래 코드를 참조하여 Form 파일을 수정합니다.

1. ① use 참조유닛 추가
2. ② 인증정보 변수와 서비스 클래스를 선언
3. ③ FormCreate 프로시저에 사업자등록상태조회 서비스 클래스 인스턴스 생성 및 초기화

```pascal
unit Example;


interface


uses
  Windows, Messages, SysUtils, Classes, Graphics, Controls, Forms, Dialogs,
  StdCtrls, TypInfo, shellapi, ExtCtrls, Grids,
  Popbill, PopbillClosedown;


const
  // API Key
  // - 연동신청 시 발급받은 인증 정보(LinkID, SecretKey로 구성)
  // • LinkID: 파트너를 식별하기 위한 고유 식별자
  // • SecretKey: API 인증토큰 발급에 사용되는 키
  //
  // TODO: 아래 LinkID, SecretKey를 발급받은 정보로 교체해 주세요.
  LinkID = 'TESTER';
  SecretKey = 'SwWxqU+0TErBXy/9TVjIPEnI0VTUMMSQZtJf3Ed8q3I=';
// 생략
// ...
// ...


var
  // 사업자등록상태조회 서비스 객체 선언
  closedownService : TClosedownService;
// 생략
// ...
// ...


procedure TfrmExample.FormCreate(Sender: TObject);
begin
  // 사업자등록상태조회 서비스 객체 초기화
  closedownService := TClosedownService.Create(LinkID,SecretKey);


  // 연동환경(테스트/운영) 설정
  // - 연동환경을 테스트 또는 운영으로 설정합니다.
  // • true: 테스트 환경으로 설정
  // • false(default) : 운영 환경으로 설정
  //
  // ※ 운영전환 이후부터 IsTest 설정 변경만으로 자유롭게  환경 전환(테스트<->운영)이 가능합니다.
  closedownService.IsTest := true;


  // 인증토큰 IP 일치 검증 사용 여부
  // - 인증토큰을 발급받은 IP와, 그 토큰을 사용하여 API를 호출하는 IP가 같은지를 검사합니다.
  //   (토큰이 외부로 유출되어도 다른 IP에서는 사용하지 못하도록 막는 보안 장치)
  // • true(사용, default) : 두 IP가 일치할 때만 API 호출 허용
  // • false(미사용) : IP 일치 검사를 생략
  //
  // ※ false는 토큰 발급 시점의 IP와 API 호출 시점의 IP가 달라질 수 있는 환경에서 사용
  //   예) 오토스케일링, 로드밸런서, NAT 등으로 호출 IP가 유동적인 클라우드 환경
  closedownService.IPRestrictOnOff := true;


  // 예외 처리 설정, true-사용, false-미사용, (기본값:true)
  closedownService.IsThrowException := true;


  // 로컬시스템 시간 사용 여부
  // - 현재시각 기준을 설정합니다.
  // • true(사용) : 로컬시스템 시간 사용
  // • false(미사용, default) : 팝빌 서버의 시간을 사용
  //
  // ※ 현재시각은 주로 인증토큰 발급 및 만료 판단 등에 사용됩니다.
  // ※ 이 설정은 홈택스 수집 기간, 세금계산서 작성일자, 발행일자 같은 업무 데이터의 날짜값을 변경하는 옵션이 아닙니다.
  // ※ 로컬 서버 시간이 정상 동기화되어 있으면 일반적으로 true를 사용하고 서버 시간 오차로 인증 실패가 의심되거나
  //   서버 시간을 신뢰하기 어려운 환경이면 false를 사용합니다.
  closedownService.UseLocalTimeYN := false;
end;
```

## 3. CheckCorpNums 기능 구현

Form에 버튼을 생성하고 버튼의 Click Event 코드에 사업자등록상태 대량조회 (CheckCorpNums) 함수를 추가합니다.

```pascal
procedure TfrmExample.btnCheckCorpNumsClick(Sender: TObject);
var
    CorpNumList : Array Of String;
    StateList : TCorpStateList;
    tmp : string;
    i : Integer;
    pbCorpNum : String;
begin
    // 팝빌회원 사업자번호
    pbCorpNum := '1234567890';


    //조회할 사업자번호 목록, 최대 1,000건
    SetLength(CorpNumList,3);
    CorpNumList[0] := '1234567890';
    CorpNumList[1] := '1234512345';
    CorpNumList[2] := '6798700433';


    try
            StateList := closedownService.checkCorpNums(CorpNumList, pbCorpNum);


    except
            on le : EPopbillException do begin
                    ShowMessage(IntToStr(le.code) + ' | ' +  le.Message);
                    Exit;
            end;
    end;


    if closedownService.LastErrCode <> 0 then
    begin
            ShowMessage(IntToStr(closedownService.LastErrCode) + ' | ' +  closedownService.LastErrMessage);
    end
    else
    begin
      tmp := '* type (사업자 과세유형) : null-알수없음, 1-일반과세자, 2-면세사업자, 3-간이과세자, 4-비영리법인, 국가기관' +#13;
      tmp := tmp + '* state (휴폐업상태) : null-알수없음, 0-등록되지 않은 사업자번호, 1-사업중, 2-폐업, 3-휴업' +#13#13;


      for i := 0 to Length(StateList) -1 do
      begin
              tmp := tmp +'corpNum(사업자번호) : '+ StateList[i].corpNum + #13;
              tmp := tmp +'type(사업자 과세유형) : '+ StateList[i].ctype + #13;
              tmp := tmp +'typeDate(과세유형 전환일자) : '+ StateList[i].typeDate + #13;
              tmp := tmp +'state(휴폐업상태) : '+ StateList[i].state + #13;
              tmp := tmp +'stateDate(휴폐업일자) : '+ StateList[i].stateDate + #13;
              tmp := tmp +'checkDate(국세청 확인일자) : '+ StateList[i].checkDate + #13#13;
      end;
      ShowMessage(tmp);
    end;
end;
```

## 4. API 응답결과 확인

API 호출 응답결과는 다음과 같습니다.

| 구분 | 응답                                                                                            |
| -- | --------------------------------------------------------------------------------------------- |
| 성공 | state(휴폐업상태) : 0 \~ 3 (1자리 문자열)                                                               |
| 실패 | code : 오류코드 (8자리 음의 정수) [\[오류코드\]](https://developers.popbill.com/error-code) message : 오류메시지 |