POPBill Developers
가이드

튜토리얼

MS Access 개발환경에서 팝빌 SDK를 추가하여 현금영수증 즉시 발행 (RegistIssue) 함수를 구현하는 예시입니다.

1. POPBiLL SDK 추가

① 팝빌 연동자료실에서 MS Access SDK 예제코드 다운로드 후 압축을 해제합니다.

② 압축해제한 현금영수증 서비스 Access 예제파일에 포함된 클래스 모듈을 기존 프로젝트의 클래스 모듈로 추가합니다.

2. POPBiLL SDK 설정

Window 폼 코드에 API Key 와 클래스를 선언하고 Form_Load() 서브모듈에 현금영수증 클래스 초기화 코드를 추가합니다.

① Form API Key, 클래스 객체 선언

Option Explicit

' 링크아이디
Private Const LinkID = "TESTER"

' 비밀키
Private Const SecretKey = "SwWxqU+0TErBXy/9TVjIPEnI0VTUMMSQZtJf3Ed8q3I="

' 현금영수증 서비스 객체 선언
Private CashbillService As New PBCBService

② Form_Load() 서브모듈

Private Sub Form_Load()

  ' 현금영수증 서비스 객체 초기화
  CashbillService.Initialize LinkID, SecretKey

  ' 연동환경 설정, True-테스트, False-운영(Production), (기본값:False)
  CashbillService.IsTest = True

  ' 인증토큰 IP 검증 설정, True-사용, False-미사용, (기본값:True)
  CashbillService.IPRestrictOnOff = True

  ' 로컬시스템 시간 사용여부, True-사용, False-미사용, (기본값:False)
  CashbillService.UseLocalTimeYN = False
End Sub

3. RegistIssue 기능 구현

Form에 버튼을 생성하고 버튼의 Click Event 코드에 현금영수증 즉시 발행 (RegistIssue) 함수 호출 코드를 작성합니다.

Private Sub btnRegistIssue_Click()
    Dim Cashbill As New PBCashbill
    Dim Response As PBResponse
    Dim corpNum As String

    ' 팝빌회원 사업자번호, "-" 제외
    corpNum = "1234567890"

    ' 문서번호
    ' 문서 관리를 위해 파트너가 할당하는 식별번호
    ' 1~24자리 영문 대소문자, 숫자, 특수문자('-','_')로 구성
    Cashbill.mgtKey = "20250314-001"

    ' 거래일시, 형식(yyyyMMddHHmmss)
    ' 발행기준 전일부터 당일까지 입력 가능
    ' 미입력시 기본값(발행일시) 처리됨
    Cashbill.tradeDT = "20250319093919"

    ' 문서형태
    Cashbill.tradeType = "승인거래"

    ' 거래구분, [소득공제용, 지출증빙용] 중 기재
    Cashbill.tradeUsage = "소득공제용"

    ' 거래유형, [일반, 도서공연, 대중교통] 중 기재
    Cashbill.tradeOpt = "일반"

    ' 과세형태, [과세, 비과세] 중 기재
    Cashbill.taxationType = "과세"

    ' 합계금액, 공급가액 + 부가세 + 봉사료
    Cashbill.totalAmount = "11000"

    ' 공급가액
    Cashbill.supplyCost = "10000"

    ' 부가세
    Cashbill.tax = "1000"

    ' 봉사료
    Cashbill.serviceFee = "0"

    ' 가맹점 사업자번호, "-" 제외 10자리
    Cashbill.franchiseCorpNum = corpNum

    ' 가맹점 종사업장 식별번호
    Cashbill.franchiseTaxRegID = ""

    ' 가맹점 상호
    Cashbill.franchiseCorpName = "발행자 상호"

    ' 가맹점 대표자 성명
    Cashbill.franchiseCEOName = "발행자 대표자"

    ' 가맹점 주소
    Cashbill.franchiseAddr = "발행자 주소"

    ' 가맹점 전화번호
    Cashbill.franchiseTEL = "070-1234-1234"

    ' 식별번호, 거래구분에 따라 작성
    ' 소득공제용 - 주민등록/휴대폰/카드번호/자진발급용 번호(010-000-1234) 기재가능
    ' 지출증빙용 - 사업자번호/주민등록/휴대폰/카드번호 기재가능
    Cashbill.identityNum = "0101112222"

    ' 주문 상품명
    Cashbill.itemName = "주문상품명"

    ' 주문번호
    Cashbill.orderNumber = "주문번호"

    ' 구매자(고객) 성명
    Cashbill.customerName = "구매자명"

    ' 구매자(고객) 이메일
    ' 팝빌 개발환경에서 테스트하는 경우에도 안내 메일이 전송되므로,
    ' 실제 구매자의 메일주소가 기재되지 않도록 주의
    Cashbill.email = "test@test.com"

    ' 구매자(고객) 휴대폰
    Cashbill.hp = "010-111-222"

    ' 구매자 알림문자 전송 여부
    ' 알림문자 전송시 포인트가 차감되며, 전송실패시 환불처리됨
    Cashbill.smssendYN = False

    Set Response = CashbillService.RegistIssue(corpNum, Cashbill)

    If Response Is Nothing Then
        MsgBox ("응답코드 : " + CStr(CashbillService.LastErrCode) + vbCrLf + "응답메시지 : " + CashbillService.LastErrMessage)
        Exit Sub
    End If

    MsgBox ("응답코드 : " + CStr(Response.code) + vbCrLf + "응답메시지 : " + Response.message + vbCrLf + "국세청승인번호 : " + Response.confirmNum + vbCrLf + "거래일자 : " + Response.tradeDate)
End Sub

4. 결과 확인

함수 호출 반환 결과는 아래와 같습니다.
- 성공 : Response code 숫자 1 반환
- 실패 : PopbillException 음의 정수 8자리 숫자값 오류코드와 오류메시지 반환 [오류코드]