튜토리얼

Visual Basic 개발환경에서 팝빌 SDK를 추가하여 단문 문자 메시지 전송 (SendSMS) 함수를 구현하는 예시입니다.

1. POPBiLL SDK 추가

① 팝빌 연동자료실에서 Visual Basic SDK 예제코드 다운로드 후 압축을 해제합니다.

② 압축해제한 SDK 예제 프로젝트의 Linkhub/ Popbill*/ 폴더에 포함된 클래스모듈을 기존 프로젝트의 클래스모듈로 추가합니다.

2. POPBiLL SDK 설정

Window 폼 코드에 API Key 와 클래스를 선언하고 Form_Load() 서브모듈에 문자 클래스 초기화 코드를 추가합니다.

① Form API Key, 클래스 객체 선언

Option Explicit

' 링크아이디
Private Const LinkID = "TESTER"

' 비밀키
Private Const SecretKey = "SwWxqU+0TErBXy/9TVjIPEnI0VTUMMSQZtJf3Ed8q3I="

' 문자 서비스 객체 선언
Private MessageService As New PBMSGService

② Form_Load() 서브모듈

Private Sub Form_Load()

  ' 문자 서비스 객체 초기화
  MessageService.Initialize LinkID, SecretKey

  ' 연동환경 설정, True-테스트, False-운영(Production), (기본값:False)
  MessageService.IsTest = True

  ' 인증토큰 IP 검증 설정, True-사용, False-미사용, (기본값:True)
  MessageService.IPRestrictOnOff = True

  ' 로컬시스템 시간 사용여부, True-사용, False-미사용, (기본값:False)
  MessageService.UseLocalTimeYN = False
End Sub

3. SendSMS 기능 구현

Form에 버튼을 생성하고 버튼의 Click Event 코드에 단문 문자 메시지 전송 (SendSMS) 함수를 작성합니다.

Private Sub btnSendSMS_One_Click()
    Dim Messages As New Collection
    Dim message As New PBMessage
    Dim adsYN As Boolean
    Dim receiptNum As String
    Dim requestNum As String
    Dim UserID As String
    Dim corpNum As String
    Dim reserveDT As String

    '팝빌회원 사업자번호
    corpNum = "1234567890"

    '팝빌회원 아이디
    UserID = "testkorea"

    '발신번호
    message.sender = "07043042991"

    '발신자명
    message.senderName = "발신자명"

    '수신번호
    message.receiver = "010111222"

    '수신자명
    message.receiverName = "수신자이름"

    '메시지 내용, 최대 90Byte 길이를 초과한 내용은 삭제되어 전송됩니다.
    message.content = "발신 내용. 단문은 90Byte로 길이가 조정되어 전송됩니다."

    Messages.Add message

    '광고문자 전송여부
    adsYN = False

    '요청번호, 파트너가 전송요청에 대한 관리번호를 직접 할당하여 관리하는 경우 기재
    '최대 36자리, 영문, 숫자, 언더바('_'), 하이픈('-')을 조합하여 사업자별로 중복되지 않도록 구성
    requestNum = ""

    '예약전송일시
    reserveDT = ""

    receiptNum = MessageService.SendSMS(corpNum, "", "", Messages, reserveDT, adsYN, UserID, requestNum)

    If receiptNum = "" Then
        MsgBox ("응답코드 : " + CStr(MessageService.LastErrCode) + vbCrLf + "응답메시지 : " + MessageService.LastErrMessage)
        Exit Sub
    End If

    MsgBox "접수 번호 : " + receiptNum

End Sub

4. 결과 확인

함수 호출 반환 결과는 아래와 같습니다.
- 성공 : Response code 로 숫자 1 반환
- 실패 : PopbillException 으로 음의 정수 8자리 숫자값 오류코드와 오류메시지 반환 [오류코드]