튜토리얼

Visual Basic 개발환경에서 팝빌 SDK를 추가하고, 전자세금계산서 즉시 발행 (RegistIssue) API를 호출하는 기본 과정을 단계별로 따라 해볼 수 있도록 구성된 가이드 입니다.

1. POPBiLL SDK 추가

① 팝빌 연동자료실에서 Visual Basic SDK 예제코드 다운로드 후 압축을 해제합니다.

② 압축해제한 SDK 예제 프로젝트의 Linkhub/ Popbill*/ 폴더에 포함된 클래스모듈을 기존 프로젝트의 클래스모듈로 추가합니다.

2. POPBiLL SDK 설정

Window 폼 코드에 API Key 와 클래스를 선언하고 Form_Load() 서브모듈에 전자세금계산서 클래스 초기화 코드를 추가합니다.

① Form API Key, 클래스 객체 선언

Option Explicit

' API Key
' - 연동신청 시 발급받은 인증 정보(LinkID, SecretKey로 구성)
' • LinkID: 파트너를 식별하기 위한 고유 식별자
' • SecretKey: API 인증토큰 발급에 사용되는 키
'
' TODO: 아래 LinkID, SecretKey를 발급받은 정보로 교체해 주세요.
Private Const LinkID = "TESTER"
Private Const SecretKey = "SwWxqU+0TErBXy/9TVjIPEnI0VTUMMSQZtJf3Ed8q3I="

' 전자세금계산서 서비스 객체 선언
Private TaxinvoiceService As New PBTIService

② Form_Load() 서브모듈

Private Sub Form_Load()

  ' 전자세금계산서 서비스 객체 초기화
  TaxinvoiceService.Initialize LinkID, SecretKey

  ' 연동환경(테스트/운영) 설정
  ' - 연동환경을 테스트 또는 운영으로 설정합니다.
  ' • True: 테스트 환경으로 설정
  ' • False(default) : 운영 환경으로 설정
  '
  ' ※ 운영전환 이후부터 IsTest 설정 변경만으로 자유롭게 환경 전환(테스트<->운영)이 가능합니다.
  TaxinvoiceService.IsTest = True

  ' 인증토큰 IP 일치 검증 사용 여부
  ' - 인증토큰을 발급받은 IP와, 그 토큰을 사용하여 API를 호출하는 IP가 같은지를 검사합니다.
  '   (토큰이 외부로 유출되어도 다른 IP에서는 사용하지 못하도록 막는 보안 장치)
  ' • True(사용, default) : 두 IP가 일치할 때만 API 호출 허용
  ' • False(미사용) : IP 일치 검사를 생략
  '
  ' ※ False는 토큰 발급 시점의 IP와 API 호출 시점의 IP가 달라질 수 있는 환경에서 사용
  '   예) 오토스케일링, 로드밸런서, NAT 등으로 호출 IP가 유동적인 클라우드 환경
  TaxinvoiceService.IPRestrictOnOff = True

  ' 로컬시스템 시간 사용 여부
  ' - 현재시각 기준을 설정합니다.
  ' • True(사용) : 로컬시스템 시간 사용
  ' • False(미사용, default) : 팝빌 서버의 시간을 사용
  '
  ' ※ 현재시각은 주로 인증토큰 발급 및 만료 판단 등에 사용됩니다.
  ' ※ 이 설정은 홈택스 수집 기간, 세금계산서 작성일자, 발행일자 같은 업무 데이터의 날짜값을 변경하는 옵션이 아닙니다.
  ' ※ 로컬 서버 시간이 정상 동기화되어 있으면 일반적으로 True를 사용하고 서버 시간 오차로 인증 실패가 의심되거나
  '   서버 시간을 신뢰하기 어려운 환경이면 False를 사용합니다.
  TaxinvoiceService.UseLocalTimeYN = False
End Sub

3. RegistIssue 기능 구현

Form에 버튼을 생성하고 버튼의 Click Event 코드에 전자세금계산서 즉시 발행 (RegistIssue) 함수를 작성합니다.

Private Sub btnRegistIssue_Click()

    Dim corpNum As String

    '팝빌회원 사업자번호
    corpNum = "1234567890"

    Dim Taxinvoice As New PBTaxinvoice

    '[필수] 작성일자, 표시형식 (yyyyMMdd)
    Taxinvoice.writeDate = "20250314"

    '[필수] 발행형태, [정발행, 역발행, 위수탁] 중 기재
    Taxinvoice.issueType = "정발행"

    '[필수] {정과금, 역과금} 중 기재, '역과금'은 역발행 프로세스에서만 이용가능
    '- 정과금(공급자 과금), 역과금(공급받는자 과금)
    Taxinvoice.chargeDirection = "정과금"

    '[필수] [영수, 청구, 없음] 중 기재
    Taxinvoice.purposeType = "영수"

    '[필수] 과세형태, [과세, 영세, 면세] 중 기재
    Taxinvoice.taxType = "과세"


    '=========================================================================
    '                              공급자 정보
    '=========================================================================

    '[필수] 공급자 사업자번호, '-' 제외 10자리
    Taxinvoice.invoicerCorpNum = corpNum

    '공급자 종사업장 식별번호. 필요시 숫자 4자리 기재
    Taxinvoice.invoicerTaxRegID = ""

    '[필수] 공급자 상호
    Taxinvoice.invoicerCorpName = "공급자 상호"

    '[필수] 공급자 문서번호, 1~24자리 (숫자, 영문, '-', '_') 조합으로
    '사업자 별로 중복되지 않도록 구성
    Taxinvoice.invoicerMgtKey = "20250314-001"

    '[필수] 공급자 대표자 성명
    Taxinvoice.invoicerCEOName = "공급자 대표자 성명"

    '공급자 주소
    Taxinvoice.invoicerAddr = "공급자 주소"

    '공급자 업태
    Taxinvoice.invoicerBizType = "공급자 업태,업태2"

    '공급자 종목
    Taxinvoice.invoicerBizClass = "공급자 종목"

    '공급자 담당자명
    Taxinvoice.invoicerContactName = "공급자 담당자명"

    '공급자 담당자 메일주소
    Taxinvoice.invoicerEmail = "test@test.com"

    '공급자 담당자 연락처
    Taxinvoice.invoicerTEL = "070-7070-0707"

    '공급자 담당자 휴대폰번호
    Taxinvoice.invoicerHP = "010-000-2222"

    ' 발행시 알림문자 전송여부 (정발행에서만 사용가능)
    ' - 공급받는자 주)담당자 휴대폰번호(invoiceeHP1)로 전송
    ' - 전송시 포인트가 차감되며 전송실패하는 경우 포인트 환불처리
    Taxinvoice.invoicerSMSSendYN = False


    '=========================================================================
    '                            공급받는자 정보
    '=========================================================================

    '[필수] 공급받는자 유형, [사업자, 개인, 외국인] 중 기재
    Taxinvoice.invoiceeType = "사업자"

    '[필수] 공급받는자 사업자번호, '-' 제외 10자리
    Taxinvoice.invoiceeCorpNum = "8888888888"

    '공급받는자 종사업장 식별번호. 필요시 숫자 4자리 기재
    Taxinvoice.invoiceeTaxRegID = ""

    '[필수] 공급받는자 상호
    Taxinvoice.invoiceeCorpName = "공급받는자 상호"

    '[역발행시 필수] 공급받는자 문서번호(역발행시 필수)
    Taxinvoice.invoiceeMgtKey = ""

    '[필수] 공급받는자 대표자 성명
    Taxinvoice.invoiceeCEOName = "공급받는자 대표자 성명"

    '공급받는자 주소
    Taxinvoice.invoiceeAddr = "공급받는자 주소"

    '공급받는자 종목
    Taxinvoice.invoiceeBizClass = "공급받는자 업종"

    '공급받는자 업태
    Taxinvoice.invoiceeBizType = "공급받는자 업태"

    '공급받는자 담당자명
    Taxinvoice.invoiceeContactName1 = "공급받는자 담당자명"

    '공급받는자 담당자 메일주소
    '팝빌 개발환경에서 테스트하는 경우에도 안내 메일이 전송되므로,
    '실제 거래처의 메일주소가 기재되지 않도록 주의
    Taxinvoice.invoiceeEmail1 = "test@invoicee.com"

    '공급받는자 담당자 연락처
    Taxinvoice.invoiceeTEL1 = "070-1234-1234"

    '공급받는자 담당자 휴대폰번호
    Taxinvoice.invoiceeHP1 = "010-111-222"


    '=========================================================================
    '                            세금계산서 정보
    '=========================================================================

    '[필수] 공급가액 합계
    Taxinvoice.supplyCostTotal = "200000"

    '[필수] 세액 합계
    Taxinvoice.taxTotal = "20000"

    '[필수] 합계금액, 공급가액 합계 + 세액합계
    Taxinvoice.totalAmount = "220000"

    '기재 상 '일련번호' 항목
    Taxinvoice.serialNum = "123"

    '기재 상 '권' 항목, 최대값 32767
    '미기재시 Taxinvoice.kwon = ""
    Taxinvoice.kwon = "1"

    '기재 상 '호' 항목, 최대값 32767
    '미기재시 Taxinvoice.ho = ""
    Taxinvoice.ho = "1"

    '기재 상 '현금' 항목
    Taxinvoice.cash = ""

    '기재 상 '수표' 항목
    Taxinvoice.chkBill = ""

    '기재 상 '어음' 항목
    Taxinvoice.note = ""

    '기재 상 '외상미수금' 항목
    Taxinvoice.credit = ""

    '기재 상 '비고'항목
    Taxinvoice.remark1 = "비고1"
    Taxinvoice.remark2 = "비고2"
    Taxinvoice.remark3 = "비고3"

    '사업자등록증 이미지 첨부여부
    Taxinvoice.businessLicenseYN = False

    '통장사본 이미지 첨부여부
    Taxinvoice.bankBookYN = False


    '=========================================================================
    '         수정세금계산서 정보 (수정세금계산서 작성시에만 기재)
    ' - 수정세금계산서 관련 정보는 연동매뉴얼 또는 개발가이드 링크 참조
    ' - [참고] 수정세금계산서 작성방법 안내 - http://blog.linkhubcorp.com/650
    '========================================================================='

    ' [수정세금계산서 작성시 필수] 수정사유코드, 수정사유에 따라 1~6중 선택기재
    Taxinvoice.modifyCode = ""

    ' [수정세금계산서 작성시 필수] 당초 국세청승인번호 기재
    Taxinvoice.orgNTSConfirmNum = ""


    '=========================================================================
    '             상세항목(품목) 정보 > 배열로 99개까지 기재 가능
    '=========================================================================

    Set Taxinvoice.detailList = New Collection

    Dim newDetail As New PBTIDetail

    newDetail.serialNum = 1             '일련번호 1부터 순차 기재
    newDetail.purchaseDT = "20250314"   '거래일자  yyyyMMdd
    newDetail.itemName = "품명"         '품목명
    newDetail.spec = "규격"             '규격
    newDetail.qty = "1"                 '수량
    newDetail.unitCost = "100000"       '단가
    newDetail.supplyCost = "100000"     '공급가액
    newDetail.tax = "10000"             '세액
    newDetail.remark = "비고"           '비고

    Taxinvoice.detailList.Add newDetail

    Dim newDetail2 As New PBTIDetail
    newDetail2.serialNum = 2             '일련번호 1부터 순차 기재
    newDetail2.purchaseDT = "20250314"   '거래일자  yyyyMMdd
    newDetail2.itemName = "품명2"        '품목명
    newDetail2.spec = "규격"             '규격
    newDetail2.qty = "1"                 '수량
    newDetail2.unitCost = "100000"       '단가
    newDetail2.supplyCost = "100000"     '공급가액
    newDetail2.tax = "10000"             '세액
    newDetail2.remark = "비고"           '비고

    Taxinvoice.detailList.Add newDetail2


    '=========================================================================
    '             추가담당자 정보 > 배열로 5개까지 기재 가능
    ' - 세금계산서 발행안내 메일을 수신받을 공급받는자 담당자가 다수인 경우
    ' 담당자 정보를 추가하여 발행안내메일을 다수에게 전송할 수 있습니다.
    '=========================================================================

    Set Taxinvoice.addContactList = New Collection
    Dim newContact As New PBTIContact
    newContact.serialNum = 1                 '일련번호, 1부터 순차기재
    newContact.ContactName = "담당자 성명"   '담당자명
    newContact.email = "test2@test.com"      '담당자 메일주소
    Taxinvoice.addContactList.Add newContact

    Dim newContact2 As New PBTIContact
    newContact2.serialNum = 2                '일련번호, 1부터 순차기재
    newContact2.ContactName = "담당자 성명"  '담당자명
    newContact2.email = "test2@test.com"     '담당자 메일주소
    Taxinvoice.addContactList.Add newContact2


    '거래명세서 동시작성 여부
    Taxinvoice.writeSpecification = False

    '거래명세서 동시작성시 거래명세서 문서번호, 미기재시 세금계산서 문서번호로 자동작성
    Taxinvoice.dealInvoiceMgtKey = ""

    '지연발행 강제여부(forceIssue)
    '발행마감일이 지난 세금계산서를 발행하는 경우, 가산세가 부과될 수 있습니다.
    '가산세가 부과되더라도 발행을 해야하는 경우에는 forceIssue의 값을
    'true로 선언하여 발행(Issue)를 호출하시면 됩니다.
    Taxinvoice.forceIssue = False

    '메모
    Taxinvoice.memo = ""

    '발행안내 메일제목, 공백처리시 기본제목으로 전송
    Taxinvoice.emailSubject = ""


    Dim Response As PBResponse

    Set Response = TaxinvoiceService.RegistIssue(corpNum, Taxinvoice)

    If Response Is Nothing Then
        MsgBox ("응답코드 : " + CStr(TaxinvoiceService.LastErrCode) + vbCrLf + "응답메시지 : " + TaxinvoiceService.LastErrMessage)
        Exit Sub
    End If

    MsgBox ("응답코드 : " + CStr(Response.code) + vbCrLf + "응답메시지 : " + Response.message + vbCrLf + "국세청승인번호 : " + Response.ntsconfirmNum)
End Sub

4. API 응답결과 확인

API 호출 응답결과는 다음과 같습니다.

구분	응답
성공	code : 1
실패	code : 오류코드 (8자리 음의 정수) [오류코드] message : 오류메시지