콘텐츠로 이동

튜토리얼

ASP 개발환경에서 팝빌 SDK를 추가하고, 전자세금계산서 즉시 발행 (RegistIssue) API를 호출하는 기본 과정을 단계별로 따라 해볼 수 있도록 구성된 가이드 입니다.

1. POPBiLL SDK 추가 및 설정

섹션 제목: “1. POPBiLL SDK 추가 및 설정”

① 팝빌 연동자료실에서 ASP SDK 예제코드 다운로드 후 압축을 해제합니다.

② 압축해제한 SDK 예제코드에 포함된 Popbill/ 폴더를 웹사이트 Root Directory 경로에 복사합니다.

③ 전자세금계산서 서비스 연동환경 설정을 위해 프로젝트 Root Directory에 common.asp 파일을 생성하고 아래의 코드를 참고하여 API Key 를 설정합니다.

<!--#include virtual="/Popbill/Popbill.asp"-->
<!--#include virtual="/Popbill/TaxinvoiceService.asp"-->


<%
  ' API Key
  ' - 연동신청 시 발급받은 인증 정보(LinkID, SecretKey로 구성)
  ' • LinkID: 파트너를 식별하기 위한 고유 식별자
  ' • SecretKey: API 인증토큰 발급에 사용되는 키
  '
  ' TODO: 아래 LinkID, SecretKey를 발급받은 정보로 교체해 주세요.
  LinkID = "LINKID"
  SecretKey = "SwWxqU+0TExEXy/9TVjKPExI2VTUMMSLZtJf3Ed8q3I="


  ' 전자세금계산서 서비스 객체 선언
  set m_TaxinvoiceService = new TaxinvoiceService


  ' 전자세금계산서 서비스 객체 초기화
  m_TaxinvoiceService.Initialize LinkID, SecretKey


  ' 연동환경(테스트/운영) 설정
  ' - 연동환경을 테스트 또는 운영으로 설정합니다.
  ' • True: 테스트 환경으로 설정
  ' • False(default) : 운영 환경으로 설정
  '
  ' ※ 운영전환 이후부터 IsTest 설정 변경만으로 자유롭게 환경 전환(테스트<->운영)이 가능합니다.
  m_TaxinvoiceService.IsTest = True


  ' 인증토큰 IP 일치 검증 사용 여부
  ' - 인증토큰을 발급받은 IP와, 그 토큰을 사용하여 API를 호출하는 IP가 같은지를 검사합니다.
  '   (토큰이 외부로 유출되어도 다른 IP에서는 사용하지 못하도록 막는 보안 장치)
  ' • True(사용, default) : 두 IP가 일치할 때만 API 호출 허용
  ' • False(미사용) : IP 일치 검사를 생략
  '
  ' ※ False는 토큰 발급 시점의 IP와 API 호출 시점의 IP가 달라질 수 있는 환경에서 사용
  '   예) 오토스케일링, 로드밸런서, NAT 등으로 호출 IP가 유동적인 클라우드 환경
  m_TaxinvoiceService.IPRestrictOnOff = True


  ' 통신 IP 고정 여부
  ' - 고객사의 보안 정책 또는 방화벽으로 인해 고정 IP로 Outbound 통신을 해야 하는 경우 사용합니다.
  ' • True(사용) : 고정(Static) IP 사용
  ' • False(미사용, default) : 가변(Elastic) IP 사용
  '
  ' ※ True 설정 시, 고정된 IP 또는 도메인을 고객사 방화벽 Outbound 목록에 등록이 필요합니다.
  '   (개발자센터 “가이드 > 공통 > 통신” 페이지에서 확인 가능)
  m_TaxinvoiceService.UseStaticIP = False


  ' 로컬시스템 시간 사용 여부
  ' - 현재시각 기준을 설정합니다.
  ' • True(사용, default) : 로컬시스템 시간 사용
  ' • False(미사용) : 팝빌 서버의 시간을 사용
  '
  ' ※ 현재시각은 주로 인증토큰 발급 및 만료 판단 등에 사용됩니다.
  ' ※ 이 설정은 홈택스 수집 기간, 세금계산서 작성일자, 발행일자 같은 업무 데이터의 날짜값을 변경하는 옵션이 아닙니다.
  ' ※ 로컬 서버 시간이 정상 동기화되어 있으면 일반적으로 True를 사용하고 서버 시간 오차로 인증 실패가 의심되거나
  '   서버 시간을 신뢰하기 어려운 환경이면 False를 사용합니다.
  m_TaxinvoiceService.UseLocalTimeYN = True
%>

2. RegistIssue 기능 구현

섹션 제목: “2. RegistIssue 기능 구현”

프로젝트에 함수 호출을 처리하는 파일을 생성하고, 아래의 코드를 참조하여 코드를 추가합니다.

<html xmlns="http://www.w3.org/1999/xhtml">
  <head>
    <meta http-equiv="Content-Type" content="text/html; charset=euc-kr" />
    <title>Popbill ASP Test.</title>
  </head>
<!--#include file="common.asp"-->
<%


  ' 팝빌회원 사업자번호
  testCorpNum = "1234567890"


  ' 거래명세서 동시작성여부
  writeSpecificationYN = False


  ' 거래명세서 동시작성시, 거래명세서 문서번호
  dealInvoiceMgtKey = ""


  ' 지연발행 강제여부
  forceIssue = False


  ' 즉시 발행 메모
  memo = "즉시 발행 메모"


  ' 발행 안내메일 제목
  emailSubject = ""


  ' 팝빌회원 아이디
  userID = "testkorea"




  ' 세금계산서 정보 객체 생성
  Set newTaxinvoice = New Taxinvoice


  ' [필수] 작성일자, 날짜형식(yyyyMMdd)
  newTaxinvoice.writeDate = "20250314"


  ' [필수] {정과금, 역과금} 중 기재, '역과금'은 역발행 프로세스에서만 이용가능
  newTaxinvoice.chargeDirection = "정과금"


  ' [필수] 발행형태, {정발행, 역발행, 위수탁} 중 기재
  newTaxinvoice.issueType = "정발행"


  ' [필수] {영수, 청구, 없음} 중 기재
  newTaxinvoice.purposeType = "영수"


  ' [필수] 과세형태,  {과세, 영세, 면세} 중 기재
  newTaxinvoice.taxType = "과세"






  '**************************************************************
  '                         공급자 정보
  '**************************************************************


  '[필수] 공급자 사업자번호, '-' 제외 10자리
  newTaxinvoice.invoicerCorpNum = "1234567890"


  '공급자 종사업장 식별번호. 필요시 숫자 4자리 기재
  newTaxinvoice.invoicerTaxRegID = ""


  '[필수] 공급자 상호
  newTaxinvoice.invoicerCorpName = "공급자 상호"


  '[필수] 공급자 문서번호, 1~24자리 (숫자, 영문, '-', '_') 조합으로
  '사업자 별로 중복되지 않도록 구성
  newTaxinvoice.invoicerMgtKey = "20220250314-001"


  '[필수] 공급자 대표자 성명
  newTaxinvoice.invoicerCEOName = "공급자 대표자 성명"


  ' 공급자 주소
  newTaxinvoice.invoicerAddr = "공급자 주소"


  ' 공급자 종목
  newTaxinvoice.invoicerBizClass = "공급자 종목"


  ' 공급자 업태
  newTaxinvoice.invoicerBizType = "공급자 업태,업태2"


  ' 공급자 담당자명
  newTaxinvoice.invoicerContactName = "공급자 담당자명"


  ' 공급자 담당자 메일주소
  newTaxinvoice.invoicerEmail = "test@test.com"


  ' 공급자 담당자 연락처
  newTaxinvoice.invoicerTEL = "070-7070-0707"


  ' 공급자 담당자 휴대폰번호
  newTaxinvoice.invoicerHP = "010-000-2222"


  '정발행시 공급받는자에게 발행안내문자 전송여부
  '- 안내문자 전송기능 이용시 포인트가 차감됩니다.
  newTaxinvoice.invoicerSMSSendYN = False






  '**************************************************************
  '                    공급받는자 정보
  '**************************************************************


  '[필수] 공급받는자 유형, [사업자, 개인, 외국인] 중 기재
  newTaxinvoice.invoiceeType = "사업자"


  '[필수] 공급받는자 사업자번호, '-' 제외 10자리
  newTaxinvoice.invoiceeCorpNum = "8888888888"


  '공급받는자 종사업장 식별번호. 필요시 숫자 4자리 기재
  newTaxinvoice.invoiceeTaxRegID = ""


  '[필수] 공급받는자 상호
  newTaxinvoice.invoiceeCorpName = "공급받는자 상호"


  '[역발행시 필수] 공급받는자 문서번호(역발행시 필수)
  newTaxinvoice.invoiceeMgtKey = ""


  '[필수] 공급받는자 대표자 성명
  newTaxinvoice.invoiceeCEOName = "공급받는자 대표자 성명"


  '공급받는자 주소
  newTaxinvoice.invoiceeAddr = "공급받는자 주소"


  '공급받는자 종목
  newTaxinvoice.invoiceeBizClass = "공급받는자 종목"


  '공급받는자 업태
  newTaxinvoice.invoiceeBizType = "공급받는자 업태"


  '공급받는자 담당자명
  newTaxinvoice.invoiceeContactName1 = "공급받는자 담당자명"


  '공급받는자 담당자 메일주소
  '팝빌 개발환경에서 테스트하는 경우에도 안내 메일이 전송되므로,
  '실제 거래처의 메일주소가 기재되지 않도록 주의
  newTaxinvoice.invoiceeEmail1 = "test@invoicee.com"


  '공급받는자 연락처
  newTaxinvoice.invoiceeTEL1 = "070-111-222"


  '공급받는자 휴대폰번호
  newTaxinvoice.invoiceeHP1 = "010-111-222"


  '역발행시 공급자에게 발행안내문자 전송여부
  newTaxinvoice.invoiceeSMSSendYN = False






  '**************************************************************
  '                        세금계산서 정보
  '**************************************************************


  '[필수] 공급가액 합계
  newTaxinvoice.supplyCostTotal = "100000"


  '[필수] 세액 합계
  newTaxinvoice.taxTotal = "10000"


  '[필수] 합계금액, 공급가액 합계 + 세액합계
  newTaxinvoice.totalAmount = "110000"


  '기재 상 '일련번호' 항목
  newTaxinvoice.serialNum = "123"


  '기재 상 '권' 항목, 최대값 32767
  newTaxinvoice.kwon = "1"


  '기재 상 '호' 항목, 최대값 32767
  newTaxinvoice.ho = "1"


  '기재 상 '현금' 항목
  newTaxinvoice.cash = ""


  '기재 상 '수표' 항목
  newTaxinvoice.chkBill = ""


  '기재 상 '어음' 항목
  newTaxinvoice.note = ""


  '기재 상 '외상미수금' 항목
  newTaxinvoice.credit = ""


  '기재 상 '비고'항목
  newTaxinvoice.remark1 = "비고1"
  newTaxinvoice.remark2 = "비고2"
  newTaxinvoice.remark3 = "비고3"


  '사업자등록증 이미지 첨부여부
  newTaxinvoice.businessLicenseYN = False


  ' 통장사본 이미지 첨부여부
  newTaxinvoice.bankBookYN = False






  '**************************************************************
  '         수정세금계산서 정보 (수정세금계산서 작성시에만 기재)
  ' - 수정세금계산서 관련 정보는 연동매뉴얼 또는 개발가이드 링크 참조
  ' - [참고] 수정세금계산서 작성방법 안내 - http://blog.linkhubcorp.com/650
  '**************************************************************


  ' [수정세금계산서 작성시 필수] 수정사유코드, 수정사유에 따라 1~6중 선택기재
  newTaxinvoice.modifyCode = ""


  ' [수정세금계산서 작성시 필수] 수정세금계산서 작성시 당초 국세청승인번호 기재
  newTaxinvoice.orgNTSConfirmNum = ""




  '**************************************************************
  '                      상세항목(품목) 정보
  '**************************************************************
  Set newDetail = New TaxinvoiceDetail
  newDetail.serialNum = 1             '일련번호 1부터 순차 기재
  newDetail.purchaseDT = "20250314"   '거래일자  yyyyMMdd
  newDetail.itemName = "품명1번"
  newDetail.spec = "규격"
  newDetail.qty = "1" '수량           ' 소숫점 2자리까지 문자열로 기재가능
  newDetail.unitCost = "50000"       ' 소숫점 2자리까지 문자열로 기재가능
  newDetail.supplyCost = "50000"
  newDetail.tax = "5000"
  newDetail.remark = "비고"


  newTaxinvoice.AddDetail newDetail


  Set newDetail = New TaxinvoiceDetail
  newDetail.serialNum = 2             '일련번호 1부터 순차 기재
  newDetail.purchaseDT = "20250314"   '거래일자  yyyyMMdd
  newDetail.itemName = "품명2번"
  newDetail.spec = "규격"
  newDetail.qty = "1" '수량           ' 소숫점 2자리까지 문자열로 기재가능
  newDetail.unitCost = "50000"       ' 소숫점 2자리까지 문자열로 기재가능
  newDetail.supplyCost = "50000"
  newDetail.tax = "5000"
  newDetail.remark = "비고"


  newTaxinvoice.AddDetail newDetail






  '**************************************************************
  '                       추가담당자 정보
  ' - 세금계산서 발행안내 메일을 수신받을 공급받는자 담당자가 다수인 경우
  '   담당자 정보를 추가하여 발행안내메일을 다수에게 전송할 수 있습니다.
  '**************************************************************


  set newContact = New Contact
  newContact.serialNum = 1
  newContact.contactName = "담당자1 성명"
  newContact.email = "test1@test.com"
  newTaxinvoice.AddContact newContact


  set newContact = New Contact
  newContact.serialNum = 2
  newContact.contactName = "담당자2 성명"
  newContact.email = "test2@test.com"
  newTaxinvoice.AddContact newContact


  On Error Resume Next


  Set Presponse = m_TaxinvoiceService.RegistIssue(testCorpNum, newTaxinvoice, writeSpecificationYN, _
              dealInvoiceMgtKey, forceIssue, memo, emailSubject, userID)


  If Err.Number <> 0 Then
    code = Err.Number
    message = Err.Description
    ntsConfirmNum = ""
    Err.Clear
  Else
    code = Presponse.code
    message =Presponse.message
    ntsConfirmNum = Presponse.ntsConfirmNum
  End If


  On Error GoTo 0
%>
  <body>
    <div id="content">
    <p class="heading1">Response</p>
    <br/>
      <fieldset class="fieldset1">
      <legend>세금계산서 즉시 발행</legend>
        <ul>
          <li>응답코드 (Response.code) : <%=code%> </li>
          <li>응답메시지 (Response.message) : <%=message%> </li>
          <% If ntsConfirmNum <> "" Then %>
          <li>국세청승인번호 (Response.ntsConfirmNum) : <%=ntsConfirmNum%> </li>
          <% End If %>
        </ul>
      </fieldset>
    </div>
  </body>
</html>

3. API 응답결과 확인

섹션 제목: “3. API 응답결과 확인”

API 호출 응답결과는 다음과 같습니다.

구분응답
성공code : 1
실패code : 오류코드 (8자리 음의 정수) [오류코드]
message : 오류메시지