콘텐츠로 이동

튜토리얼

ASP 개발환경에서 팝빌 SDK를 추가하고, 카카오톡 알림톡 전송 (SendATS) API를 호출하는 기본 과정을 단계별로 따라 해볼 수 있도록 구성된 가이드 입니다.

1. POPBiLL SDK 추가 및 설정

섹션 제목: “1. POPBiLL SDK 추가 및 설정”

① 팝빌 연동자료실에서 ASP SDK 예제코드 다운로드 후 압축을 해제합니다.

② 압축해제한 SDK 예제코드에 포함된 Popbill/ 폴더를 웹사이트 Root Directory 경로에 복사합니다.

③ 카카오톡 서비스 연동환경 설정을 위해 프로젝트 Root Directory에 common.asp 파일을 생성하고 아래의 코드를 참고하여 API Key 를 설정합니다.

<!--#include virtual="/Popbill/Popbill.asp"-->
<!--#include virtual="/Popbill/KakaoService.asp"-->


<%
  ' API Key
  ' - 연동신청 시 발급받은 인증 정보(LinkID, SecretKey로 구성)
  ' • LinkID: 파트너를 식별하기 위한 고유 식별자
  ' • SecretKey: API 인증토큰 발급에 사용되는 키
  '
  ' TODO: 아래 LinkID, SecretKey를 발급받은 정보로 교체해 주세요.
  LinkID = "LINKID"
  SecretKey = "SwWxqU+0TExEXy/9TVjKPExI2VTUMMSLZtJf3Ed8q3I="


  ' 카카오톡 서비스 객체 선언
  set m_KakaoService = new KakaoService


  ' 카카오톡 서비스 객체 초기화
  m_KakaoService.Initialize LinkID, SecretKey


  ' 연동환경(테스트/운영) 설정
  ' - 연동환경을 테스트 또는 운영으로 설정합니다.
  ' • True: 테스트 환경으로 설정
  ' • False(default) : 운영 환경으로 설정
  '
  ' ※ 운영전환 이후부터 IsTest 설정 변경만으로 자유롭게 환경 전환(테스트<->운영)이 가능합니다.
  m_KakaoService.IsTest = True


  ' 인증토큰 IP 일치 검증 사용 여부
  ' - 인증토큰을 발급받은 IP와, 그 토큰을 사용하여 API를 호출하는 IP가 같은지를 검사합니다.
  '   (토큰이 외부로 유출되어도 다른 IP에서는 사용하지 못하도록 막는 보안 장치)
  ' • True(사용, default) : 두 IP가 일치할 때만 API 호출 허용
  ' • False(미사용) : IP 일치 검사를 생략
  '
  ' ※ False는 토큰 발급 시점의 IP와 API 호출 시점의 IP가 달라질 수 있는 환경에서 사용
  '   예) 오토스케일링, 로드밸런서, NAT 등으로 호출 IP가 유동적인 클라우드 환경
  m_KakaoService.IPRestrictOnOff = True


  ' 통신 IP 고정 여부
  ' - 고객사의 보안 정책 또는 방화벽으로 인해 고정 IP로 Outbound 통신을 해야 하는 경우 사용합니다.
  ' • True(사용) : 고정(Static) IP 사용
  ' • False(미사용, default) : 가변(Elastic) IP 사용
  '
  ' ※ True 설정 시, 고정된 IP 또는 도메인을 고객사 방화벽 Outbound 목록에 등록이 필요합니다.
  '   (개발자센터 “가이드 > 공통 > 통신” 페이지에서 확인 가능)
  m_KakaoService.UseStaticIP = False


  ' 로컬시스템 시간 사용 여부
  ' - 현재시각 기준을 설정합니다.
  ' • True(사용, default) : 로컬시스템 시간 사용
  ' • False(미사용) : 팝빌 서버의 시간을 사용
  '
  ' ※ 현재시각은 주로 인증토큰 발급 및 만료 판단 등에 사용됩니다.
  ' ※ 이 설정은 홈택스 수집 기간, 세금계산서 작성일자, 발행일자 같은 업무 데이터의 날짜값을 변경하는 옵션이 아닙니다.
  ' ※ 로컬 서버 시간이 정상 동기화되어 있으면 일반적으로 True를 사용하고 서버 시간 오차로 인증 실패가 의심되거나
  '   서버 시간을 신뢰하기 어려운 환경이면 False를 사용합니다.
  m_KakaoService.UseLocalTimeYN = True
%>

2. SendATS 기능 구현

섹션 제목: “2. SendATS 기능 구현”

프로젝트에 함수 호출을 처리하는 파일을 생성하고, 아래의 코드를 참조하여 코드를 추가합니다.

<html xmlns="http://www.w3.org/1999/xhtml">
  <head>
    <meta http-equiv="Content-Type" content="text/html; charset=euc-kr" />
    <title>Popbill Kakaotalk Test.</title>
  </head>
<!--#include file="common.asp"-->
<%


  '팝빌 회원 사업자번호, "-" 제외
  testCorpNum = "1234567890"


  '팝빌 회원 아이디
  testUserID = "testkorea"


  '알림톡 템플릿 코드 - 템플릿 목록 조회 (ListATSTemplate API)의 반환항목 확인
  templateCode = "019020000163"


  '팝빌에 사전 등록된 발신번호
  senderNum = "  07043042992"


  '알림톡 내용, 최대 1000자
  content = "[ 팝빌 ]" & vbCrLf
  content = content + "신청하신 #{템플릿코드}에 대한 심사가 완료되어 승인 처리되었습니다." & vbCrLf
  content = content + "해당 템플릿으로 전송 가능합니다." & vbCrLf & vbCrLf
  content = content + "문의사항 있으시면 파트너센터로 편하게 연락주시기 바랍니다. " & vbCrLf & vbCrLf
  content = content + "팝빌 파트너센터 : 1600-8536" & vbCrLf
  content = content + "support@linkhubcorp.com"


  '대체문자 내용
  altContent = "대체문자 메시지 내용"


  '대체문자 전송유형 공백-미전송, A-대체문자내용 전송, C-알림톡내용 전송
  altSendType = "C"


  '예약전송시간 yyyyMMddHHmmss, reserveDT값이 없는 경우 즉시전송
  reserveDT = ""


  Set receiverList = CreateObject("Scripting.Dictionary")


  '메시지 전송정보
  Set rcvInfo = New KakaoReceiver


  '수신자번호
  rcvInfo.rcv = "01011222"


  '수신자명
  rcvInfo.rcvnm = " 수신자이름"


  receiverList.Add 0, rcvInfo


  '요청번호 (팝빌 회원별 비중복 번호 할당)
  '영문,숫자,'-','_' 조합, 최대 36자
  requestNum = ""


  ' 알림톡 버튼정보를 템플릿 신청시 기재한 버튼정보와 동일하게 전송하는 경우 btnList를 선언만 하고 함수호출.
  Set btnList = CreateObject("Scripting.Dictionary")


  '알림톡 버튼 URL에 #{템플릿변수}를 기재한경우 템플릿변수 영역을 변경하여 버튼정보 구성
  'Set btnInfo = New KakaoButton
  'btnInfo.n = "템플릿 안내"
  'btnInfo.t = "WL"
  'btnInfo.u1 = "https://www.popbil.com"
  'btnInfo.u2 = "http://www.llinkhubcorp.com"
  'btnList.Add 0, btnInfo


  '대체 문자 발송 시 전송될 제목
  '장문(LMS)일 때만 전송
  altSubject = "대체문자 제목"


  On Error Resume Next


  receiptNum = m_KakaoService.SendATS(testCorpNum, templateCode, senderNum,  _
  content, altContent, altSendType, reserveDT, receiverList, requestNum, testUserID, btnList, altSubject)


  If Err.Number <> 0 then
    code = Err.Number
    message =  Err.Description
    Err.Clear
  End If


  On Error GoTo 0
%>
  <body>
    <div id="content">
    <p class="heading1">Response</p>
    <br/>
    <fieldset class="fieldset1">
    <legend>알림톡 1건 전송</legend>
    <% If code = 0 Then %>
      <ul>
        <li>ReceiptNum(접수번호) : <%=receiptNum%> </li>
      </ul>
    <%  Else  %>
      <ul>
        <li>Response.code: <%=code%> </li>
        <li>Response.message: <%=message%> </li>
      </ul>
    <%  End If  %>
    </fieldset>
    </div>
  </body>
</html>

3. API 응답결과 확인

섹션 제목: “3. API 응답결과 확인”

API 호출 응답결과는 다음과 같습니다.

구분응답
성공ReceiptNum(접수번호) : 18자리 문자열
실패code : 오류코드 (8자리 음의 정수) [오류코드]
message : 오류메시지