튜토리얼

ASP 개발환경에서 팝빌 SDK를 추가하고, 팩스 전송 (SendFAX) API를 호출하는 기본 과정을 단계별로 따라 해볼 수 있도록 구성된 가이드 입니다.

1. POPBiLL SDK 추가 및 설정

① 팝빌 연동자료실에서 ASP SDK 예제코드 다운로드 후 압축을 해제합니다.

② 압축해제한 SDK 예제코드에 포함된 Popbill/ 폴더를 웹사이트 Root Directory 경로에 복사합니다.

③ 팩스 서비스 연동환경 설정을 위해 프로젝트 Root Directory에 common.asp 파일을 생성하고 아래의 코드를 참고하여 API Key 를 설정합니다.

<!--#include virtual="/Popbill/Popbill.asp"-->
<!--#include virtual="/Popbill/FaxService.asp"-->

<%
  ' API Key
  ' - 연동신청 시 발급받은 인증 정보(LinkID, SecretKey로 구성)
  ' • LinkID: 파트너를 식별하기 위한 고유 식별자
  ' • SecretKey: API 인증토큰 발급에 사용되는 키
  '
  ' TODO: 아래 LinkID, SecretKey를 발급받은 정보로 교체해 주세요.
  LinkID = "LINKID"
  SecretKey = "SwWxqU+0TExEXy/9TVjKPExI2VTUMMSLZtJf3Ed8q3I="

  ' 팩스 서비스 객체 선언
  set m_FaxService = new FaxService

  ' 팩스 서비스 객체 초기화
  m_FaxService.Initialize LinkID, SecretKey

  ' 연동환경(테스트/운영) 설정
  ' - 연동환경을 테스트 또는 운영으로 설정합니다.
  ' • True: 테스트 환경으로 설정
  ' • False(default) : 운영 환경으로 설정
  '
  ' ※ 운영전환 이후부터 IsTest 설정 변경만으로 자유롭게 환경 전환(테스트<->운영)이 가능합니다.
  m_FaxService.IsTest = True

  ' 인증토큰 IP 일치 검증 사용 여부
  ' - 인증토큰을 발급받은 IP와, 그 토큰을 사용하여 API를 호출하는 IP가 같은지를 검사합니다.
  '   (토큰이 외부로 유출되어도 다른 IP에서는 사용하지 못하도록 막는 보안 장치)
  ' • True(사용, default) : 두 IP가 일치할 때만 API 호출 허용
  ' • False(미사용) : IP 일치 검사를 생략
  '
  ' ※ False는 토큰 발급 시점의 IP와 API 호출 시점의 IP가 달라질 수 있는 환경에서 사용
  '   예) 오토스케일링, 로드밸런서, NAT 등으로 호출 IP가 유동적인 클라우드 환경
  m_FaxService.IPRestrictOnOff = True

  ' 통신 IP 고정 여부
  ' - 고객사의 보안 정책 또는 방화벽으로 인해 고정 IP로 Outbound 통신을 해야 하는 경우 사용합니다.
  ' • True(사용) : 고정(Static) IP 사용
  ' • False(미사용, default) : 가변(Elastic) IP 사용
  '
  ' ※ True 설정 시, 고정된 IP 또는 도메인을 고객사 방화벽 Outbound 목록에 등록이 필요합니다.
  '   (개발자센터 “가이드 > 공통 > 통신” 페이지에서 확인 가능)
  m_FaxService.UseStaticIP = False

  ' 로컬시스템 시간 사용 여부
  ' - 현재시각 기준을 설정합니다.
  ' • True(사용, default) : 로컬시스템 시간 사용
  ' • False(미사용) : 팝빌 서버의 시간을 사용
  '
  ' ※ 현재시각은 주로 인증토큰 발급 및 만료 판단 등에 사용됩니다.
  ' ※ 이 설정은 홈택스 수집 기간, 세금계산서 작성일자, 발행일자 같은 업무 데이터의 날짜값을 변경하는 옵션이 아닙니다.
  ' ※ 로컬 서버 시간이 정상 동기화되어 있으면 일반적으로 True를 사용하고 서버 시간 오차로 인증 실패가 의심되거나
  '   서버 시간을 신뢰하기 어려운 환경이면 False를 사용합니다.
  m_FaxService.UseLocalTimeYN = True
%>

2. SendFAX 기능 구현

프로젝트에 함수 호출을 처리하는 파일을 생성하고, 아래의 코드를 참조하여 코드를 추가합니다.

<html xmlns="http://www.w3.org/1999/xhtml">
  <head>
    <meta http-equiv="Content-Type" content="text/html; charset=euc-kr" />
    <title>Popbill FAX Test.</title>
  </head>
  <!--#include file="common.asp"-->
  <%
  '팝빌 회원 사업자번호, "-" 제외
  testCorpNum = "1234567890"

  '팝빌 회원 아이디
  userID = "testkorea"

  '발신자 번호
  sendNum = "07043042992"

  '전송예약시간 yyyyMMddHHmmss,  공백처리시 즉시전송
  reserveDT = ""

  '수신자 정보
  Dim receivers(0)
  Set receivers(0) = New FaxReceiver

  '수신번호
  receivers(0).receiverNum = "070111222"

  '수신자명
  receivers(0).receiverName = "수신자 명칭"

  '팩스전송할 파일 (최대 30개)
  FilePaths = Array("C:\popbill.example.asp\대한민국헌법.doc","C:\popbill.example.asp\test.jpg")

  '광고팩스 전송여부
  adsYN = False

  '팩스제목
  title = "ASP  팩스 전송 테스트"

  '요청번호 (팝빌 회원별 비중복 번호 할당)
  '영문,숫자,'-','_' 조합, 최대 36자
  requestNum = ""

  On Error Resume Next

  url = m_FaxService.SendFAX(testCorpNum, sendNum, receivers, FilePaths, reserveDT, userID, adsYN, title, requestNum)

  If Err.Number <> 0 then
    code = Err.Number
    message = Err.Description
    Err.Clear
  End If

  On Error GoTo 0
  %>
  <body>
    <div id="content">
      <p class="heading1">Response</p>
      <br/>
      <fieldset class="fieldset1">
      <legend>팩스 전송</legend>
        <ul>
        <% If code = 0 Then %>
          <li>receiptNum (접수번호) : <%=url%> </li>
        <% Else %>
          <li>Response.code : <%=code%> </li>
          <li>Response.message : <%=message%> </li>
        <% End If %>
        </ul>
      </fieldset>
    </div>
  </body>
</html>

3. API 응답결과 확인

API 호출 응답결과는 다음과 같습니다.

구분	응답
성공	ReceiptNum(접수번호) : 18자리 문자열
실패	code : 오류코드 (8자리 음의 정수) [오류코드] message : 오류메시지