튜토리얼

Visual Basic 개발환경에서 팝빌 SDK를 추가하여 사업자등록상태 대량조회 (CheckCorpNums) 함수를 구현하는 예시입니다.

1. POPBiLL SDK 추가

① 팝빌 연동자료실에서 Visual Basic SDK 예제코드 다운로드 후 압축을 해제합니다.

② 압축해제한 SDK 예제 프로젝트의 Linkhub/ Popbill*/ 폴더에 포함된 클래스모듈을 기존 프로젝트의 클래스모듈로 추가합니다.

2. POPBiLL SDK 설정

Window 폼 코드에 API Key 와 클래스를 선언하고 Form_Load() 서브모듈에 사업자등록상태조회 클래스 초기화 코드를 추가합니다.

① Form API Key, 클래스 객체 선언

Option Explicit

' 링크아이디
Private Const LinkID = "TESTER"

' 비밀키
Private Const SecretKey = "SwWxqU+0TErBXy/9TVjIPEnI0VTUMMSQZtJf3Ed8q3I="

' 사업자등록상태조회 서비스 객체 선언
Private ClosedownService As New PBCDService

② Form_Load() 서브모듈

Private Sub Form_Load()

  ' 사업자등록상태조회 서비스 객체 초기화
  ClosedownService.Initialize LinkID, SecretKey

  ' 연동환경 설정, True-테스트, False-운영(Production), (기본값:False)
  ClosedownService.IsTest = True

  ' 인증토큰 IP 검증 설정, True-사용, False-미사용, (기본값:True)
  ClosedownService.IPRestrictOnOff = True

  ' 로컬시스템 시간 사용여부, True-사용, False-미사용, (기본값:False)
  ClosedownService.UseLocalTimeYN = False
End Sub

3. CheckCorpNums 기능 구현

Form에 버튼을 생성하고 버튼의 Click Event 코드에 사업자등록상태 대량조회 (CheckCorpNums) 함수를 작성합니다.

Private Sub btnCheckCorpNums_Click()
    Dim resultList As Collection
    Dim CorpNumList As New Collection
    Dim tmp As String
    Dim state As PBCorpState
    Dim corpNum As String

    '팝빌회원 사업자번호
    corpNum = "1234567890"

    '조회할 사업자번호 배열 (최대 1,000건)
    CorpNumList.Add "1234567890"
    CorpNumList.Add "679-87-00433"
    CorpNumList.Add "123-12-12312"

    Set resultList = ClosedownService.CheckCorpNums(corpNum, CorpNumList)

    If resultList Is Nothing Then
        MsgBox ("응답코드 : " + CStr(ClosedownService.LastErrCode) + vbCrLf + "응답메시지 : " + ClosedownService.LastErrMessage)
        Exit Sub
    End If

    tmp = tmp + "* state (휴폐업상태) : null-알수없음, 0-등록되지 않은 사업자번호, 1-사업중, 2-폐업, 3-휴업" + vbCrLf
    tmp = tmp + "* type (과세유형 전환일자) : null-알수없음, 1-일반과세자, 2-면세과세자, 3-간이과세자, 4-비영리법인, 국가기관" + vbCrLf + vbCrLf

    For Each state In resultList
        tmp = tmp + "corpNum (사업자번호) : " + state.corpNum + vbCrLf
        tmp = tmp + "state (휴폐업상태) : " + state.state + vbCrLf
        tmp = tmp + "type (사업자 과세유형) : " + state.ctype + vbCrLf
        tmp = tmp + "typeDate (과세유형 전환일자) : " + state.typeDate + vbCrLf
        tmp = tmp + "stateDate (휴폐업일자) : " + state.stateDate + vbCrLf
        tmp = tmp + "checkDate (국세청 확인일자) : " + state.checkDate + vbCrLf + vbCrLf
    Next

    MsgBox tmp, , "사업자등록상태조회 - 대량"
End Sub

4. 결과 확인

함수 호출 반환 결과는 아래와 같습니다.
- 성공 : state(휴폐업상태) 숫자 0~3 반환
- 실패 : PopbillException 음의 정수 8자리 숫자값 오류코드와 오류메시지 반환 [오류코드]