튜토리얼
ASP 개발환경에서 팝빌 SDK를 추가하여 팩스 전송 (SendFAX) 함수를 구현하는 예시입니다.
1. POPBiLL SDK 추가 및 설정
① 팝빌 연동자료실에서 ASP SDK 예제코드 다운로드 후 압축을 해제합니다.
② 압축해제한 SDK 예제코드에 포함된 Popbill/ 폴더를 웹사이트 Root Directory 경로에 복사합니다.
③ 팩스 서비스 연동환경 설정을 위해 프로젝트 Root Directory에 common.asp 파일을 생성하고 아래의 코드를 참고하여 API Key 를 설정합니다.
<!--#include virtual="/Popbill/Popbill.asp"-->
<!--#include virtual="/Popbill/FaxService.asp"-->
<%
' 링크아이디
LinkID = "LINKID"
' 비밀키
SecretKey = "SwWxqU+0TExEXy/9TVjKPExI2VTUMMSLZtJf3Ed8q3I="
' 팩스 서비스 객체 선언
set m_FaxService = new FaxService
' 팩스 서비스 객체 초기화
m_FaxService.Initialize LinkID, SecretKey
' 연동환경 설정, True-테스트, False-운영(Production), (기본값:False)
m_FaxService.IsTest = True
' 인증토큰 IP 검증 설정, True-사용, False-미사용, (기본값:True)
m_FaxService.IPRestrictOnOff = True
' 통신 IP 고정, True-사용, False-미사용, (기본값:False)
m_FaxService.UseStaticIP = False
' 로컬시스템 시간 사용여부, True-사용, False-미사용, (기본값:True)
m_FaxService.UseLocalTimeYN = True
%>2. SendFAX 기능 구현
프로젝트에 함수 호출을 처리하는 파일을 생성하고, 아래의 코드를 참조하여 코드를 추가합니다.
<html xmlns="http://www.w3.org/1999/xhtml">
<head>
<meta http-equiv="Content-Type" content="text/html; charset=euc-kr" />
<title>Popbill FAX Test.</title>
</head>
<!--#include file="common.asp"-->
<%
'팝빌 회원 사업자번호, "-" 제외
testCorpNum = "1234567890"
'팝빌 회원 아이디
userID = "testkorea"
'발신자 번호
sendNum = "07043042992"
'전송예약시간 yyyyMMddHHmmss, 공백처리시 즉시전송
reserveDT = ""
'수신자 정보
Dim receivers(0)
Set receivers(0) = New FaxReceiver
'수신번호
receivers(0).receiverNum = "070111222"
'수신자명
receivers(0).receiverName = "수신자 명칭"
'팩스전송할 파일 (최대 20개)
FilePaths = Array("C:\popbill.example.asp\대한민국헌법.doc","C:\popbill.example.asp\test.jpg")
'광고팩스 전송여부
adsYN = False
'팩스제목
title = "ASP 팩스 전송 테스트"
'요청번호 (팝빌 회원별 비중복 번호 할당)
'영문,숫자,'-','_' 조합, 최대 36자
requestNum = ""
On Error Resume Next
url = m_FaxService.SendFAX(testCorpNum, sendNum, receivers, FilePaths, reserveDT, userID, adsYN, title, requestNum)
If Err.Number <> 0 then
code = Err.Number
message = Err.Description
Err.Clears
End If
On Error GoTo 0
%>
<body>
<div id="content">
<p class="heading1">Response</p>
<br/>
<fieldset class="fieldset1">
<legend>팩스 전송</legend>
<ul>
<% If code = 0 Then %>
<li>recepitNum (접수번호) : <%=url%> </li>
<% Else %>
<li>Response.code : <%=code%> </li>
<li>Response.message : <%=message%> </li>
<% End If %>
</ul>
</fieldset>
</div>
</body>
</html>3. 결과 확인
함수 호출 반환 결과는 아래와 같습니다.
- 성공 : Response code 로 숫자 1 반환
- 실패 : PopbillException 으로 음의 정수 8자리 숫자값 오류코드와 오류메시지 반환 [오류코드]